Bit Of VBA Help Please {SOLVED}

[Steve001]

Morning

Having a bit of trouble if someone can help me out - I know this is not matrix related have asked for assistance on an excel forum but no reply yet

Trying to merge several excel workbooks found this code on Microsoft site but cannot get it working . have read that there are differences in the way DIR works with excel 2008 and 2010 ?

I am using home and business 2010

code based here

https://msdn.microsoft.com/en-us/librar ... e.14).aspx

Code: Select all

Sub MergeAllWorkbooks()
    Dim SummarySheet As Worksheet
    Dim FolderPath As String
    Dim NRow As Long
    Dim FileName As String
    Dim WorkBk As Workbook
    Dim SourceRange As Range
    Dim DestRange As Range
    
    ' Create a new workbook and set a variable to the first sheet. 
    Set SummarySheet = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
    
    ' Modify this folder path to point to the files you want to use.
    FolderPath = "C:\Users\Peter\invoices"
    
    ' NRow keeps track of where to insert new rows in the destination workbook.
    NRow = 1
    
    ' Call Dir the first time, pointing it to all Excel files in the folder path.
    FileName = Dir(FolderPath & "*.xl*")
    
    ' Loop until Dir returns an empty string.
    Do While FileName <> ""
        ' Open a workbook in the folder
        Set WorkBk = Workbooks.Open(FolderPath & FileName)
        
        ' Set the cell in column A to be the file name.
        SummarySheet.Range("A" & NRow).Value = FileName
        
        ' Set the source range to be A9 through C9.
        ' Modify this range for your workbooks. 
        ' It can span multiple rows.
        Set SourceRange = WorkBk.Worksheets(1).Range("A9:C9")
        
        ' Set the destination range to start at column B and 
        ' be the same size as the source range.
        Set DestRange = SummarySheet.Range("B" & NRow)
        Set DestRange = DestRange.Resize(SourceRange.Rows.Count, _
           SourceRange.Columns.Count)
           
        ' Copy over the values from the source to the destination.
        DestRange.Value = SourceRange.Value
        
        ' Increase NRow so that we know where to copy data next.
        NRow = NRow + DestRange.Rows.Count
        
        ' Close the source workbook without saving changes.
        WorkBk.Close savechanges:=False
        
        ' Use Dir to get the next file name.
        FileName = Dir()
    Loop
    
    ' Call AutoFit on the destination sheet so that all 
    ' data is readable.
    SummarySheet.Columns.AutoFit
End Sub

stopping here

FileName = Dir(FolderPath & "*.xl*")

FileName is blank for some reason

major stressed have spent far to long trying to get this to work

If someone can help me

Steve


solution

FolderPath = "C:\Users\Peter\invoices"

should be FolderPath = "C:\Users\Peter\invoices\"

[Steve001]

better version much simpler

Code: Select all

Sub test()
Dim FolderPath As String
Dim filename As String
Dim filename2 As String

' this sheet name
filename2 = "merge test 2.xlsm"


Application.ScreenUpdating = False
FolderPath = "Z:\file location here "
filename = Dir(FolderPath & "*.xl*")

Do While filename <> ""

'MsgBox (filename)

    ' Open Raw Data Workbook
    Set x = Workbooks.Open(FolderPath & filename)
        Workbooks(filename).Activate

 
    ' Copy data to a variable
    Application.DisplayAlerts = False
    x.Sheets("Report").Range("A:BB").Copy
    Workbooks(filename).Close
    
    On Error Resume Next
    ' Paste the data into the correct sheet
    Workbooks(fname2).Activate
    Sheets("Report").Select
    ActiveSheet.Range("A:BB").PasteSpecial xlPasteAll
   

 ' Use Dir to get the next file name.
        filename = Dir()

Loop

' Call AutoFit on the destination sheet so that all data is readable.

Workbooks(filename2).Activate

Columns("A:Z").Select

   Selection.EntireColumn.AutoFit

End Sub

Steve